Hit Counter

Accelerating Charges and Associated Inertial and Radiation Reaction Forces

G.R.Dixon, 02/13/2010

1. The Inertial Reaction Force.

A point charge can be modeled as the limit of a spherical shell of charge as the charge’s radius goes to zero. Since the spherical shell’s electromagnetic mass is inversely proportional to its radius:

, (1_1)

the mass of the point charge is infinite. In order to give a resting point charge a finite acceleration (no matter how slight), an infinite force must be applied:

. (1_2)

Of course by Newton’s 3rd law a charge exerts an equal, oppositely directed "inertial" force on an accelerating agent. An interesting postulate is that this inertial reaction force is an electric force, experienced by a charge in its own, acceleration-induced E field.

By way of an example, let us suppose that at time t=0 point charge q, at rest at the origin of a rectangular coordinate system, is experiencing a constant acceleration in the +x direction. That is, at t=0,

, (1_3)

, (1_4)

. (1_5)

Using the point charge field solutions, we can compute Ex at a set of points on the +y axis. Fig. 1_1 shows the results of such a calculation. Ex approaches negative infinity as y approaches zero. Evidently the point charge experiences an infinite "self-force" opposing its acceleration.

Figure 1_1

Ex Right At an Accelerating, Point Charge

The idea of an uncharged particle exerting a force on itself is of course disallowed in Newtonian mechanics. In deference to that rule, it may be more acceptable to think that a point charge acts as a link between the driving agent and the electromagnetic field. Any positive work done by the agent on the field is matched by negative work done by the field on the agent (and vice versa).

It is noteworthy that a negative point charge (or its driving agent) also experiences an inertial reaction force when it is accelerated. To the extent all neutral matter is ultimately composed of charges (quarks), it appears plausible that all inertial effects can be traced to acceleration-induced electric fields.

2. The Radiation Reaction Force.

Abraham and Lorentz were first to theorize that a charge experiences a radiation reaction force when its acceleration varies in time. Their formula for any charge distribution (including our point charge) is

= . (2_1)

As in Sect. 1, we can specify a motion on the x axis and then compute Ex at a set of points on the +y axis. When this is done, extrapolation to y=0 indicates that, here too, the radiation reaction force is an electric force experienced by the charge in its own da/dt-induced E field.

Let us suppose that at t=0 our point charge’s motion is

dax/dt=constant,      (2_2)

, (2_3)

=0, (2_4)

=0. (2_5)

At time t=0 the charge is at rest on the x axis and is not accelerating. Fig. 2_1 plots the computed Ex at a set of points on the +y axis. Note that in this case Ex is single-valued for all y axis points considered. Indeed is is found that

, (2_6)

quite as Abraham-Lorentz and the Lorentz force law specify.

Figure 2_1

Ex Right At a Point Charge with Nonzero dax/dt

3. Conclusions.

Point charges with non-uniform motion have acceleration-induced and da/dt-induced electric fields. To the extent these fields exist right at a charge, the driving agent is subject to Newtonian reaction forces. Inertial reaction forces are associated with nonzero accelerations. Radiation reaction forces occur when da/dt is nonzero.

Since all "neutral" matter is ultimately composed of charged particles (quarks), it seems likely that all reaction forces are the sums of electric forces.

***Appendix***

Option Explicit

Private Sub cmdConstanta_Click()

'*******************

'Compute Ex at points on the y-axis ranging from y=.01m to y=.0001m

'when a is constant positive, retarded v is negative and

'retarded x is positive.

'Output the computed values of Ex for plotting purposes.

'*******************

'Physical and mathematical constants follow.

Const c As Double = 299792000 'Speed of light

Const epsilon0 As Double = 0.00000000000885 'Permittivity Constant

Const pi As Double = 3.14159265358979

Const Steps As Long = 5000 'Number of y-axis points

Const Pymax As Double = 0.01 'Max value for y (in meters)

Const Pymin As Double = 0.0001

Const deltay As Double = (Pymax - Pymin) / Steps 'Distance between y values

Const a As Double = 10

Const ar As Double = 10

Const q As Double = 1 '1-coul point charge is modeled

Const t As Double = 0 'All Ex computations occur at t=0

'Variables follow.

Dim i As Long 'Loop index

Dim Py(Steps) As Double 'Points at which Ex is computed

Dim tr As Double 'Retarded time

Dim dt As Double 't-tr

Dim dtmin As Double 'Minimum value for dt

Dim dtmax As Double 'maximum value for dt

Dim xr As Double 'Retarded position on x-axis

Dim vr As Double 'Retarded velocity

Dim Drx As Double 'x-component of vector Dr

Dim Dry As Double 'y-component of vector Dr

Dim Dr As Double 'Magnitude of vector Dr

Dim ux As Double 'x-component of vector u

Dim uy As Double 'y-component of vector u

Dim Ex(Steps) As Double 'x-component of electric field vector

'Executable code follows.

'First set up the field evaluation points.

For i = 0 To Steps - 1

Py(i) = Pymin + i * deltay

Next i

'Then compute the retarded time, position, velocity and acceleration.

For i = 0 To Steps - 1

dtmin = 0

dtmax = Sqr(Py(i) ^ 2 + 10 ^ 2) / c

Do

dt = (dtmax + dtmin) / 2

tr = t - dt

xr = a * tr ^ 2 / 2

If Abs(c * dt - Sqr(xr ^ 2 + Py(i) ^ 2)) < 2 ^ (-30) Then Exit Do

If c * dt - Sqr(xr ^ 2 + Py(i) ^ 2) > 0 Then

dtmax = dt

Else

dtmin = dt

End If

Loop

vr = a * tr

'Now compute the components and magnitude of the vector Dr.

Drx = -xr

Dry = Py(i)

Dr = Sqr(Drx ^ 2 + Dry ^ 2)

'Compute the components of vector u.

ux = c * Drx / Dr - vr

uy = c * Dry / Dr

'Compute the x-components of the electric field.

Ex(i) = q / (4 * pi * epsilon0) * ((Dr / (Drx * ux + Dry * uy) ^ 3) * (ux * (c ^ 2 - vr ^ 2) - Dry * uy * ar))

'Repeat for every value of y.

Next i

'Write the values of Ex out for plotting purposes.

Open "c:\WINMCADC\Physics\POSSect1a1.prn" For Output As 1

For i = 0 To Steps - 1

Write #1, Py(i), Ex(i)

Next i

Close 1

MsgBox ("Ready for plotting.")

End Sub

Private Sub cmdConstdadt_Click()

'*******************

'Compute Ex at points on the y-axis ranging from y=.2m to y=1m

'when da/dt is constant positive.

'Output the computed values of Ex for plotting purposes.

'*******************

'Physical and mathematical constants follow.

Const c As Double = 299792000 'Speed of light

Const epsilon0 As Double = 0.00000000000885 'Permittivity Constant

Const pi As Double = 3.14159265358979

Const Steps As Long = 5000 'Number of y-axis points

Const Pymax As Double = 1 'Max value for y (in meters)

Const Pymin As Double = 0.2

Const deltay As Double = (Pymax - Pymin) / Steps 'Distance between y values

Const dadt As Double = 10 'Constant value for da/dt (m/sec/sec/sec)

Const q As Double = 1 '1-coul point charge is modeled

Const t As Double = 0 'All Ex computations occur at t=0

'Variables follow.

Dim i As Long 'Loop index

Dim Py(Steps) As Double 'Points at which Ex is computed

Dim tr As Double 'Retarded time

Dim dt As Double 't-tr

Dim dtmin As Double 'Minimum value for dt

Dim dtmax As Double 'maximum value for dt

Dim xr As Double 'Retarded position on x-axis

Dim vr As Double 'Retarded velocity

Dim ar As Double 'Retarded acceleration

Dim Drx As Double 'x-component of vector Dr

Dim Dry As Double 'y-component of vector Dr

Dim Dr As Double 'Magnitude of vector Dr

Dim ux As Double 'x-component of vector u

Dim uy As Double 'y-component of vector u

Dim Ex(Steps) As Double 'x-component of electric field vector

Dim ExTruncated(Steps) As Double 'Truncated E field (for plotting)

Dim ExAverage, ExTheoretical As Double

'Executable code follows.

'First set up the field evaluation points.

For i = 0 To Steps - 1

Py(i) = Pymin + i * deltay

Next i

'Then compute the retarded time, position, velocity and acceleration.

For i = 0 To Steps - 1

dtmin = 0

dtmax = Sqr(Py(i) ^ 2 + 10 ^ 2) / c

Do

dt = (dtmax + dtmin) / 2

tr = t - dt

xr = dadt * tr ^ 3 / 6

If Abs(c * dt - Sqr(xr ^ 2 + Py(i) ^ 2)) < 2 ^ (-30) Then Exit Do

If c * dt - Sqr(xr ^ 2 + Py(i) ^ 2) > 0 Then

dtmax = dt

Else

dtmin = dt

End If

Loop

vr = dadt * tr ^ 2 / 2

ar = dadt * tr

'Now compute the components and magnitude of the vector Dr.

Drx = -xr

Dry = Py(i)

Dr = Sqr(Drx ^ 2 + Dry ^ 2)

'Compute the components of vector u.

ux = c * Drx / Dr - vr

uy = c * Dry / Dr

'Compute the x-components of the electric field.

Ex(i) = q / (4 * pi * epsilon0) * ((Dr / (Drx * ux + Dry * uy) ^ 3) * (ux * (c ^ 2 - vr ^ 2) - Dry * uy * ar))

'(Truncate to 5 significant digits for plotting purposes)

ExTruncated(i) = (Fix(Ex(i) * 1E+19)) * 1E-19

'Repeat for every value of y.

Next i

'Average the computed values of Ex.

ExAverage = 0

For i = 0 To Steps - 1

ExAverage = ExAverage + Ex(i)

Next i

ExAverage = ExAverage / Steps

'Compute the theoretical value for Ex.

ExTheoretical = q / (6 * pi * epsilon0 * c ^ 3) * dadt

MsgBox ("ExTheoretical = " & ExTheoretical & ", ExAverage = " & ExAverage)

'See how well ExAverage and ExTheoretical match

MsgBox ("(Average value of Ex)/(Theoretical value for Ex) = " & ExAverage / ExTheoretical)

'Write the values of Truncated Ex out for plotting purposes.

Open "c:\WINMCADC\Physics\POSSect1a1.prn" For Output As 1

For i = 0 To Steps - 1

Write #1, Py(i), ExTruncated(i)

Next i

Close 1

MsgBox ("Ready for plotting.")

End Sub