Oscillating Charge and the Emitted Radiant Energy per Cycle

                                G.R..Dixon, July 27, 2014

Hit Counter

Introduction.

In this article the radiant power emitted by an oscillating point charge is discussed.  Two formulas are considered: (1) the Larmor-Lienard formula, and (2) the Abraham-Lorentz formula.  Both formulas are relativistically rigorous.  Thus each applies to cases where the maximum speed of oscillation may range up to ~c.  Consideration is limited to one dimension, where a point charge moves back and forth along the x-axis.

 

Background.

We begin by acknowledging that an oscillating charge does in fact radiate.  Let us suppose that a 1-coulomb point charge has the motion

 

x = A sin(wt),                                                                                                 (1)

 

where A = 1 meter and wA = .9c.  We assume that the charge is driven by an agent contact (non-electromagnetic) force.  Appendix 1 contains a Basic program that computes the energy flux per cycle through an enclosing spherical surface.  By energy conservation, that flux should equal the power radiated by the charge, integrated over one cycle time.  The result is:

 

Fenergy = 65064229862 joules.                                                                   (2)

 

Larmor-Lienard.

For the motion specified in Eq. 1, the Larmor-Lienard formula for radiated power is

 

Prad(LL) = q2g6a2 / (6peoc3).                                                                            (3)

 

The program in Appendix 2 does the numerical integration, calling the result Wrad(LL) (for the work expended per cycle by the driving agent).  The result is

 

Wrad(LL) = 65064225853 joules,                                                                  (4)

 

in excellent agreement with Eq. 2.

 

Abraham-Lorentz.

Abraham and Lorentz reasoned that the radiation field of an oscillated charge exerts a recoil force on the charge and thence (assuming the point charge is not a sink of momentum) on the driving agent.  They dubbed this the radiation reaction force, Frad_react.  The formula for this force is

 

Frad_react = q2 / (6peoc3)(g4 da/dt + ¾ a dg4/dt)                                             (5)

              = q2 / (6peoc3)(g4 da/dt + 3g6va2/c2).

 

By Newton’s 3rd law, at least part of the driving agent action force must be equal and oppositely directed to Frad_react.  The power expended by this force is thus

 

Prad(AL) = -q2 / (6peoc3)(g4v da/dt + 3g6v2a2/c2).                                           (6)

 

The work per cycle, expended by the driving agent, is then the definite integral of Prad(AL) over the limits zero to 2p/w.  Appendix 3 does this integration, and the result is

 

Wrad(AL) = 65064225952 joules,                                                                  (7)

 

in excellent agreement with Eqs. 2 and 4.

 

Larmor-Lienard vs. Abraham-Lorentz.

It seems reasonable to divide the Larmor-Lienard formula for Prad(LL) by v, in order to obtain the force exerted by the driving agent.  For motion confined to the x-axis,

 

Frad(LL) = q2g6a2 / (6peoc3v).                                                                           (8)

 

In the case of Abraham-Lorentz we would have (See Eq. 6)

Frad(AL) = -q2 / (6peoc3)(g4 da/dt + 3g6va2/c2).                                               (9)

 

Evidently Larmor-Lienard implies an infinite agent force at x = +A, whereas Abraham-Lorentz has a finite agent force at all x.  Despite such singularities in Frad(LL), Frad(LL)v integrates to the same radiated energy per cycle as Frad(AL)v does ... an amazing result.

 

 

***Appendix 1***

 

Private Sub cmdComputeEnergyFlux_Click()

'*********

'Compute the Poynting Vector, at points on the spherical surface,

'at times throughout an oscillating charge cycle time.  Integrate

'its normal component wrt surface area and time to get the energy

'flux per cycle through the surface.

'*********

 

'Physical and mathematical constants

Const c As Double = 299792000 'speed of light

Const epsilon0 As Double = 0.00000000000885 'permittivity constant

Const pi As Double = 3.14159265358979

Const Steps As Long = 500   'steps in an oscillation

Const A As Double = 1   'amplitude of oscillation

Const R As Double = 2 * A   'radius of enclosing sphere

Const omega As Double = 0.9 * c / A 'angular frequency

Const tau As Double = 2 * pi / omega 'period of oscillation

Const deltat As Double = tau / Steps 'time between computed epochs

Const q As Double = 1 'charge of one coulomb

Const dtheta As Double = 2 * pi / 360

 

'Variables

Dim i, j As Long 'loop index

Dim t As Double  'current time

Dim theta As Double 'angle with x-axis

Dim dArea As Double 'area increment of spherical surface

Dim Px, Py As Double    'location of area increment

Dim x, y As Double  'location of charge

Dim nx, ny As Double    'normal to area increment

Dim Ex, Ey, Bz, Sx, Sy As Double    'fields, Poynting

Dim SNormal, EFlux, EFluxTotal As Double

Dim tr As Double    'retarded time

Dim dt As Double    't-tr

Dim dtmin As Double 'minimum value for dt

Dim dtmax As Double 'maximum value for dt

Dim xr As Double    'retarded position

Dim vr As Double    'retarded velocity

Dim ar As Double    'retarded acceleration

Dim Drx As Double   'x component of Dr

Dim Dry As Double   'y component of Dr

Dim Dr As Double    'magnitude of vector Dr

Dim ux As Double    'x component of vector u

Dim uy As Double    'y component of vector u

 

'Program variables

EFluxTotal = 0

For i = 0 To Steps - 1

    Screen.MousePointer = vbHourglass

    t = i * deltat

    x = A * Sin(omega * t)

    y = 0

       

'Set up the angles and surface increments

    For j = 0 To 179

        theta = (j + 0.5) * dtheta

        dArea = 2 * pi * R * Sin(theta) * R * dtheta

        Px = R * Cos(theta)

        Py = R * Sin(theta)

        nx = cos(theta)

        ny = sin(theta)       

        dtmin = 0

        dtmax = 2 * (R + A) / c

        'Find retarded time, position components

        Do

            dt = (dtmax + dtmin) / 2

            tr = t - dt

            xr = A * Sin(omega * tr)

            Drx = Px - xr

            Dry = Py

            Dr = Sqr(Drx ^ 2 + Dry ^ 2)

            If Abs(c * dt - Dr) < 2 ^ (-30) Then Exit Do

            If c * dt - Dr > 0 Then

                dtmax = dt

            Else

                dtmin = dt

            End If

        Loop

        'Compute E and B field components

        vr = omega * A * Cos(omega * tr)

        ar = -(omega ^ 2) * A * Sin(omega * tr)

        ux = c * Drx / Dr - vr

        uy = c * Dry / Dr

        Ex = q / (4 * pi * epsilon0) * ((Dr / (Drx * ux + Dry * uy) ^ 3) * (ux * (c ^ 2 - vr ^ 2) - Dry * uy * ar))

        Ey = q / (4 * pi * epsilon0) * ((Dr / (Drx * ux + Dry * uy) ^ 3) * (uy * (c ^ 2 - vr ^ 2) + Drx * uy * ar))

        Bz = 1 / (Dr * c) * (Drx * Ey - Dry * Ex)

        'Compute Poynting components

        Sx = epsilon0 * c ^ 2 * (Ey * Bz)

        Sy = epsilon0 * c ^ 2 * (-Ex * Bz)

        SNormal = Sx * nx + Sy * ny

        'Compute energy flux

        EFlux = SNormal * dArea * deltat

        EFluxTotal = EFluxTotal + EFlux

    Next j

Next i

Screen.MousePointer = vbDefault

'Display total energy flux per cycle

MsgBox ("ERad = " & EFluxTotal)

Stop

 

End Sub

 

 

***Appendix 2***

 

Private Sub cmdComputeLarmorWrad_Click()

'***Compute Wrad(LL) from formula.

 

    Const pi As Double = 3.141592654

    Const eps0 As Double = 0.00000000000885

    Const q As Double = 1

    Const c As Double = 299792000#

    Const ConTerm As Double = q ^ 2 / (6 * pi * eps0 * c ^ 3)

    Const N As Long = 500

    Const Amp As Double = 1

    Const omega As Double = 0.9 * c / Amp

    Const tau As Double = 2 * pi / omega

    Const dt = tau / N

    Dim Wrad As Double

    Dim t As Double

    Dim Sum As Double

    Dim Term As Double

    Dim i As Long

    Dim v, a, dadt, gamma As Double

           

    Sum = 0

    For i = 0 To N - 1

        t = i * dt

        v = omega * Amp * Cos(omega * t)

        a = -omega ^ 2 * Amp * Sin(omega * t)

        gamma = 1 / Sqr(1 - v ^ 2 / c ^ 2)

        Term = gamma ^ 6 * a ^ 2

        Term = Term * dt

        Sum = Sum + Term

    Next i

    Sum = ConTerm * Sum

    MsgBox ("Sum = " & Sum)

 

End Sub

 

 

 

***Appendix 3***

 

Private Sub CmdComputeAbrahamLorentzWrad_Click()

'***Compute Wrad(AL) from formula.

 

    Const pi As Double = 3.141592654

    Const eps0 As Double = 0.00000000000885

    Const q As Double = 1

    Const c As Double = 299792000#

    Const ConTerm As Double = -q ^ 2 / (6 * pi * eps0 * c ^ 3)

    Const N As Long = 500

    Const Amp As Double = 1

    Const omega As Double = 0.9 * c / Amp

    Const tau As Double = 2 * pi / omega

    Const dt = tau / N

    Dim Wrad As Double

    Dim t As Double

    Dim Sum As Double

    Dim Term As Double

    Dim i As Long

    Dim v, a, dadt, gamma As Double

           

    Sum = 0

    For i = 0 To N - 1

        t = i * dt

        v = omega * Amp * Cos(omega * t)

        a = -omega ^ 2 * Amp * Sin(omega * t)

        dadt = -omega ^ 3 * Amp * Cos(omega * t)

        gamma = 1 / Sqr(1 - v ^ 2 / c ^ 2)

        Term = gamma ^ 4 * v * dadt

        Term = Term + 3 * gamma ^ 6 * v ^ 2 * a ^ 2 / c ^ 2

        Term = Term * dt

        Sum = Sum + Term

    Next i

    Sum = ConTerm * Sum

    MsgBox ("Sum = " & Sum)

           

End Sub