Hit Counter

On the Radiated Power of an Oscillating Charge

G.R.Dixon, September 30, 2008

 

1.  A Conundrum.

A point charge, q, has the motion

    . (1_1)

Classically, such a charge radiates power at some rate Prad. According to the Larmor formula, this rate of radiation is

    . (1_2)

Note that PLar is zero as q passes through the Origin, and it is at a maximum at x=+A.

Presumably Eq. 1_1 is only possible if q is driven by some force, F. The rate at which F does work is

    . (1_3)

v is maximum at x=0 and is zero at x=+A. Here, then, is a conundrum: PLar has a maximum at x=+A, whereas P is zero at those points. This inequality is inconsistent with the idea that, at any moment, PLar must be some fraction of P.

        2.  Self-Forces and F.

If the point charge in Sect. 1 is replaced by a small charge distribution, then it is readily demonstrated that the oscillating charge will experience two distinct self-forces in its own electric field(1,2). The first of these self-forces is proportional to –a and might be dubbed the inertial reaction force. That is, if melecmag is the constant of proportionality, then

    . (2_1)

The second self-force is called the radiation reaction force, and is proportional to da/dt. It was first suggested by Abraham and Lorentz and is dependent only upon q (i.e., not on the distribution specifics). Its non-relativistic formula is

    . (2_2)

Now just as some external agent (usually implied) must counteract the electric force that each charge increment in a distribution experiences, in the electrostatic E field of the other increments (when the distribution is permanently at rest), so must the same agent counteract the inertial and radiation reaction force components when the charge has a motion like the one specified in Eq. 1_1. In brief, at least part of F must equate to the negative of the inertial and radiation reaction forces:

    , (2_3)

where 0<f<1.

It is noteworthy that –FRadReact has its maximum amplitude at x=0. The same is true for v. Indeed for the motion in Eq. 1_1, FRadReact and v are p out of phase. FRadReact is therefore analogous to a frictional drag force. It is also noteworthy that –FRadReact.v does the same amount of work per cycle as PLar does. That is, for the motion specified by Eq. 1_1,

    , (2_4)

whereas

    , (2_5)

and

    . (2_6)

The difference, of course, is that PLar and –FRadReact.v are p/2 out of phase. For convenience, let us define the Abraham-Lorentz rate at which radiant power is created to be

    . (2_7)

Can the conundrum posed in Sect. 1 be solved by using PAL in lieu of PLar? Let us see.

 

        3.  A Problem with PAL.

A more or less axiomatic assumption in field theory is that the action of a driving force cannot be manifest at a distant point sooner than a light signal from the application point could reach said distant point. Since the amplitude of PAL=–FRadReact.v is maximum at t=0, we might test the idea that PAL equates to Prad by computing the Poynting vector, S, at (say) y=10(2p/c)=10l from time t=10(2p/w) to t=11(2p/w). Fig. 3_1 plots the computed value of Sy(t). Fig. 3_2 plots PLar(t) and PAL(t) over the time interval t=0 to t=2p/w. (PLar is in red and PAL is in blue. The Visual Basic program that computes the data points is provided at the end of this article.)

Figure 3_1

                                          

Sy(t), y=10l

Figure 3_2

                                                  

Prad(t) and –FRadReact.v(t)

Comparison of Figs. 3_1 and 3_2 indicates that the computed Sy(t) is p/2 out of phase with PAL! Indeed Fig. 3_2 indicates that PLar is in phase with Sy(t). Not only do the figures seem to argue against the equivalence of PAL and Prad; they argue in favor of the equivalence of Prad and PLar. And they do this notwithstanding the argument against PLar in Sect. 1!

 

        4.  A Suggested Resolution.

The problems with PLar and PAL are mutually solved if we adopt the following idea: PAL is the rate at which energy that will be radiated is added to the charge. And PLar is the rate at which energy is radiated. In other words, PAL and PLar both play a role in the phenomenon of radiation.

This of course implies that energy is not radiated when –FRadReact does work, but rather is held by the charge and emitted later, as specified by PLar. It implies that there is a mechanism whereby a charge can hold work that is done upon it until PLar indicates that it be emitted.

How can such energy be stored by a point charge? To the extent point charges have infinite electromagnetic mass and probably do not exist in nature, the question may be moot. But such is not the case for finite charge distributions.

What, then, might a mechanism be (generally speaking) in cases of finite charge distributions? Perhaps a clue lies in the idea that, relativistically, a distribution’s charge density presumably varies as its speed varies. And this may constitute a temporary energy sink/well.

We shall not pursue the details of such a distribution-dependent mechanism here. Suffice it to say that

  • PAL is the rate at which energy, destined to be radiated, is added to an oscillating charge;

  • PLar is the rate at which such energy is actually radiated;

  • Since PAL and PLar are p/2 out of phase (in cases of periodic motion), it must be that the charge has the ability to store radiant energy for brief periods of time.

  •         ---------------------------------------------------------------------------------------------------------------------------------------------------------------------

    (1)  See Sect. 9.3.2, "The Physical Origin of the Radiation Reaction," Introduction to Electrodynamics, 2nd Edition, David J. Griffiths.

    (2)  For a demonstration of the electric nature of the radiation reaction force in a case of non-oscillatory motion, see A Real-Life Example of the Radiation Reaction Force.

    -----------------------------------------------------------------------------------------------------------------------------------------------------------

    Visual Basic Program

    Option Explicit

    Private Sub cmdALText_Click()

        'Constants follow.

        Const steps As Long = 5000

        Const pi As Double = 3.14159265

        Const eps0 As Double = 0.00000000000885

        Const c As Double = 299792000 'Speed of light

        Const Ampl As Double = 0.001 'Amplitude of oscillation

        Const vmax As Double = 0.01 * c 'Maximum speed

        Const omega As Double = vmax / Ampl 'Angular frequency of oscillation

        Const freq As Double = omega / (2 * pi) 'Frequency of oscillation

        Const tau As Double = 1 / freq 'Period of oscillation

        Const deltat As Double = tau / steps 'Time between epochs

        Const q As Double = 1 'Magnitude of point charge

        Const lambda As Double = 2 * pi * c / omega 'Wavelength of radiated light

        Const fary As Double = 10 * lambda 'Field evaluation point

        Const vry As Double = 0 'Retarded velocity

        Const Dy As Double = fary 'Distance from field eval. pt. to retarded position

        'Variables follow.

        Dim t(steps), t1(steps) As Double 'Computation times

        Dim Ex, Ey As Double 'Electric field, E

        Dim Bz As Double 'Magnetic field, B

        Dim Sy(steps) As Double 'Poynting vector, S

        Dim PLar(steps), PAL(steps), v, a, dadt As Double

        Dim tr As Double 'Retarded time

        Dim ux, uy As Double 'Utility vectors

        Dim Dx, D As Double 'D is distance from fld eval. pt. to retarded position

        Dim dt As Double 'Current time minus retarded time

        Dim xr As Double 'Retarded position

        Dim vrx As Double 'Retarded velocity

        Dim vr As Double 'Retarded speed

        Dim arx As Double 'Retarded acceleration

        Dim dtmin, dtmax As Double 'Trial values of dt

        Dim index As Long 'Loop Counter

        'Compute values for PAL (Abraham-Lorentz radiated power) and PLar (Larmor radiated power).

        For index = 0 To steps - 1

            t1(index) = index * deltat 'Time at origin

            v = omega * Ampl * Cos(omega * t1(index))

            a = -omega ^ 2 * Ampl * Sin(omega * t1(index)) 'Acceleration at time t1

            dadt = -omega ^ 3 * Ampl * Cos(omega * t1(index))

            PAL(index) = -q ^ 2 / (6 * pi * eps0 * c ^ 3) * dadt * v

            PLar(index) = q ^ 2 / (6 * pi * eps0 * c ^ 3) * a ^ 2

        Next index

        'Then compute the Poynting Vector point on the y axis.

        For index = 0 To steps - 1

            Debug.Print index

            t(index) = 10 * tau + index * deltat

            dtmin = 0

            dtmax = Sqr((2 * Ampl) ^ 2 + fary ^ 2) / c

            Do

                dt = (dtmin + dtmax) / 2

                tr = t(index) - dt 'Trial retarded time

                xr = Ampl * Sin(omega * tr) 'Trial retarded x

                Dx = -xr

                D = Sqr(Dx ^ 2 + Dy ^ 2)

                If Abs(c * dt - D) < 2 ^ -30 Then Exit Do 'Test for best retarded time

                If (c * dt - D) > 0 Then dtmax = dt

                If (c * dt - D) < 0 Then dtmin = dt

            Loop

            'Once the retarded time is known, calculate the retarded kinematic variables.

            vrx = omega * Ampl * Cos(omega * tr)

            vr = vrx

            arx = -omega ^ 2 * Ampl * Sin(omega * tr)

            ux = c * Dx / D - vrx

            uy = c * Dy / D

            'Then compute the electric field...

            Ex = q / (4 * pi * eps0) * D / (Dx * ux + Dy * uy) ^ 3 * (ux * (c ^ 2 - vr ^ 2) + Dy * (-uy * arx))

            Ey = q / (4 * pi * eps0) * D / (Dx * ux + Dy * uy) ^ 3 * (uy * (c ^ 2 - vr ^ 2))

            '...and the magnetic field...

            Bz = 1 / (c * D) * (Dx * Ey - Dy * Ex)

            '...and finally the Poynting vector.

            Sy(index) = eps0 * c ^ 2 * (-Ex * Bz)

        Next index

        'Once the fields and Poynting vector have been computed, output computed variables for plotting.

        Open "c:\WINMCADC\Physics\ALTest.PRN" For Output As #1

        For index = 0 To steps - 1

            Write #1, t(index) / tau, Sy(index), t1(index), PLar(index), PAL(index)

        Next index

        Close

        MsgBox ("Ready for plotting data")

        Stop

    End Sub

    .